Contenido
|
- Cada comando debe ir en una nueva linea.
- Las macros pueden contener un máximo de 255 caracteres.
- Los nombres de habilidades y objetos deberán escribirse en el idioma activo del juego, tal y como figura en la descripción que se muestran en el juego.
- No se pueden lanzar dos hechizos en la misma macro si el tiempo de reutilización o el Cooldown de uno afecta al siguiente hechizo (incluyendo el Cooldown Global). Sólo en algunos casos funciona con hechizos instantáneos intercalando el comando /stopcasting entre cada hechizo.
- No existen comandos de pausa o retardo.
1. Abrir ventana de edición de macros pulsando el botón macros del menú principal (tecla Esc), o directamente se escribe desde el chat el comando ‘/macro’.
2. En el editor de macros se pulsa el botón ‘Nuevo’ para crear una nueva macro; seleccionar un icono y un nombre y pulsar ‘Aceptar’.
3. En el cuadro de texto se escribe la secuencia de comandos, uno por linea.
4. Una vez completada la macro arrastramos su icono correspondiente a un hueco de una de las barras de acciones.
5. Para ejecutar la macro pulsamos en el botón de acción o la tecla asignada al mismo.
NOTA: Los comandos están en inglés aunque muchos tienen su equivalente en español, pero en inglés suelen ser más cortos y por el límite de 255 caracteres, es mejor usar éstos.
Cambios en 2.0
En el parche 2.0, coincidiendo con la salida de la expansión La Cruzada Ardiente (Abrv. TBC), se presenta un nuevo sistema de macros con nuevas restricciones pero también posibilidades. En primer lugar: En las macros de TBC no se podrán seleccionar unidades o lanzar hechizos con el interfaz de /script cuando se inicien. Esto quiere decir que la siguiente macro:
/script if (UnitMana(”player”)>54) then CastSpellByName(”Golpe Heroico”); end
….ya no funcionará. La función CastSpellByName() no podrá ser llamada en combate, y TargetUnit(), TargetByName() y funciones similares no serán accesibles ni dentro ni fuera de combate. Otras tantas funciones se han deshabilitado para cuando los personajes estén en combate. No las recuerdo todas de memoria, pero algunas de ellas son las de mascotas: PetAttack() PetF`ollow() PetPassiveMode() PetAggresiveMode() SpellStopCasting(), cambiar de barra de acciones, no será posible programáticamente sin una previa interacción del usuario y a través de las denominadas Plantillas seguras. Estos serán reemplazados con comandos (/slash) que podrán ser usados.
Sintáxis
/comando [opción] acción; [opción1, opción2] acción
El nuevo formato del comando ‘/cast’ (/lanzar) es:
/lanzar [<primer conjunto de opciones>] <primer hechizo>; [<segundo conjunto de opciones>]
<segundo hechizo> ; [<tercer conjunto de opciones>] <tercer hechizo>; …
Trucos que se pueden usar con las opciones
- Puedes añadir un ‘no’ al comienzo de cada opción (excepto target) para invertirla, ej. con ‘nocombat’ solo se ejecutará si no se está en combate.
- Separar las opciones con coma ‘,’ funcionará como una sentencia ‘Y’; si ambas opciones son ciertas, se ejecuta.
- Separar opciones con la barra ‘/’ funcionará a modo de sentencia ‘Ó’; si cualquiera de las dos se cumple, se ejecuta.
- Seleccionando el icono de interrogación ‘?’ en el Editor de Macro, forzará a que la macro presente el icono de hechizo actual de la opción de ‘feedback’.(es decir, muestra el mismo icono del hechizo indicando además el estado de enfriamiento o cooldown).
- Pueden indicarse varias cláusulas de condiciones para una acción simple, que será ejecutada si cualquiera de las cláusulas es verdadera. Ej.
…(sería como si cada bloque de corchetes estuviera separado por un ‘Ó’ lógico).
Feedback
- El feedback significa que se mostrará el estado de cierta habilidad u objeto en el icono de la macro (enfriamiento, si se puede usar o no, etc).
- y -son prefijos de comentarios en las macros.
- Una macro que comience con # show <item o hechizo> usará el feedback para ese hechizo, # show none no mostrará feedback.
- De otra manera el primer comando /cast, /randomcast, /castsequence, /use, o /randomuse (/lanzar) será usado para el feedback.
- Las secuencias realmente ciclan el item/hechizo mostrado en el feedback para que corresponda con el siguiente paso de la secuencia.
- show y #showtooltip ahora pueden recibir condiciones para actualizarse dinámicamente (ver Opciones más abajo)
- A #show y #showtooltip puede facilitarse un número de ranura para que muestre el estado de esa ranura. También se les pueden aplicar condiciones en el mismo formato que /lanzar.
Lanzamiento de Hechizos(casting)
- Cuando se lanza una mejora que tiene un rango demasiado alto para un objetivo amigable, el juego automáticamente aplicará el mayor rango posible para el objetivo.
- Las habilidades alternables tendrán un retraso de 1.5 segundos tras ser lanzadas antes de que puedan ser canceladas haciendo click sobre ellas, para prevenir que puedan cancelarse por error. En cualquier caso todavía se puede hacer click derecho para cancelarse.
La manera en que ahora funcionan las macros es la siguiente: La primera opción se evalúa. Si es cierta, entonces el primer hechizo se lanza. Si son falsas, el siguiente conjunto de opciones se comprueba, y si se cumplen, se lanza el siguiente hechizo, y así sucesivamente. Sin embargo ten en cuenta que sólo un hechizo se puede lanzar simultáneamente. Tan pronto como un conjunto de opciones sea considerada verdadera, el juego lanza el hechizo correspondiente y esa línea de la macro ya está hecha.
El primer hechizo en una macro que falle prevendrá de futuros lanzamientos en la macro como si el enfriamiento (cooldown) global de 1.5 seg hubiera saltado. A los comandos /cast, /use, /cancelaura, /changeactionbar, /equip, /target, /focus, /assist, /targetenemy, /targetfriend, /targetparty, y /targetraid se les pueden asignar múltiples acciones y condiciones sobre las que usar esas acciones. La primera acción coincidente será usada. (Esto se entiende mejor en los ejemplos).
Los nombres de items pueden usarse intercaladas con nombres hechizos en /cast, /castrandom, y /castsequence. Venenos, alimentar a la mascota, etc., será incluso más fácil en las macros: /cast Feed Pet (/lanzar Alimentar Mascota) y luego /use Costillas de cerdo secas. También se podrá hacer click en la comida en la barra de acciones cuando tengas seleccionado Alimentar a la mascota u otros objetos de hechizo con selección.
Comandos
(NOTA: los caracteres < > se utilizan para delimitar los parámetros, pero no deben escribirse)
-Comandos de acción
/cancel – Cancela la acción en curso
/cancelaura – Cancela el aura activa
/focus – Establece el objetico como foco (ver más abajo)
/stopmacro – Detiene la ejecución de la macro
/cancelform – Cancela la forma actual (druida, sacerdote sombras, etc)
-Barra de acciones
/changeactionbar <num> – Cambia de barra de acción
/swapactionbar <num1> <num2> – Intercambia dos barras de acción
-Atacar
/startattack [unidad] – Comienza a atacar a la unidad (target, focus, targettarget, focustarget, etc)
/stopattack – Detiene el ataque
-Ventajas(buffs)/Auras
/cancelaura <nombre> – Cancela un aura como si se hubiera pulsado el botón derecho sobre ella
/cancelform – Cancela cualquier forma (formas druida, forma de sombra sacerdote, etc)
-Hechizos/habilidades
/cast <hechizo> – Lanza/usa un hechizo/habilidad
/castrandom <hechizo1>,<hechizo2>,<hechizo3> – intentará lanzar uno de los hechizos
indicados de manera aleatoria
/castsequence – Lanza una secuencia de hechizos (explicado más abajo)
/stopcasting – intentará cancelar el hechizo que se está lanzando actualmente
-Objetos y Equipo
/equip <nombreObj> – Equipa un objeto
/equip <item:id> – Equipa un objeto con id /equip item:25640
/equipslot <ranura> <nombreObj> – Equipa un objeto en una ranura dada (Actualmente bug)
/use <nombreObj> – Usa un objeto por su nombre
/use <ranura> – Usa el objeto que haya en una ranura
/use <idbolsa> <ranurabolsa> – Usa un objeto que haya la ranura de una bolsa
/userandom <item1>, <item2>, <item3> – Intentará usar aleatoriamente uno de los objetos indicados
-Control de Mascota
/petaggressive – Pone la mascota en modo agresivo
/petattack – Ordena atacar a la mascota
/petautocaston <spell> – Activa el modo auto de una habilidad de mascota
/petautocastoff <spell> – Desactiva el modo auto de una habilidad de mascota
/petdefensive – Pone la mascota en modo defensivo
/petfollow – Pone la mascota en modo seguimiento
/petpassive – Pone la mascota en modo pasivo
/petstay – Ordena a la mascota quedarse quieta
/petautocasttoggle <habilidad> – Alterna el modo automático de la habilidad de la mascota
-Selección Objetivo
/assist – Asiste al objetivo actual
/clearfocus – Elimina el foco actual
/cleartarget – Deselecciona el objetivo actual
/target <nombre> – Selecciona a un objetivo con un nombre similar
/targetexact <nombre> – Selecciona a un objetivo cuyo nombre coincida exactamente con el indicado
-Ciclo de Objetivo
/targetenemy – Selecciona el enemigo más cercano
/targetlastenemy – Selecciona al último enemigo
/targetfriend – Selecciona el amigo más cercano
/targetlastfriend – Selecciona al último amigo
/targetlasttarget – Selecciona como objetivo el último objetivo que se tuvo
/targetparty – Selecciona el objetivo del grupo más cercano
/targetraid – Selecciona el objetivo de la banda más cercano
-Comandos de Banda
/mt <nombre> – Designa al jugador tanque principal por nombre o por objetivo seleccionado
/mtoff <nombre> – Limpia el tanque principal por nombrado o por objetivo seleccionado
/clearmt – Limpia todos los papeles de tanque principal
/ma <nombre> – Designa el jugador asistente principal
/maoff <nombre> – Limpia el asistente principal por nombre o por objetivo seleccionado
/clearma – Limpia todos los asistentes principales
-Montura
/dismount – Desmonta (No hay comando /mount pero se puede usar /use Nombre Montura)
-Secuencia de Hechizos
Permite establecer una serie de hechizos para que se lancen uno detrás de otro en cada click de la macro. Cuando finalice la secuencia, volverá al comienzo. El formato es el siguiente:
/castsequence [<opciones>] reset=<#>/target/combat <hechizo1>, <hechizo2>, <hechizo3>
- La línea de ‘reset’ puede especificar un número de segundos después de los cuales la secuencia se resetea y por tanto vuelve al principio, o si se debería resetear al cambiar de objetivo o dejar el combate.
- La secuencia rastrea el siguiente hechizo en la secuencia hasta que se resetea, y el siguiente hechizo solo avanza si el lanzamiento tiene éxito.
- Se puede especificar una condición al comienzo del comando, antes del reset, para filtrar cuando se usará la secuencia.(No se puede establecer una condición para cada hechizo por separado).
- Se pueden utilizar tanto objetos como hechizos.
- Si el hechizo falla en el lanzamiento (debido al cooldown, fuera de rango, son mana suficiente, etc) entonces la secuencia no pasa al siguiente hechizo. La próxima vez que se pulse en la macro lo intentará lanzar de nuevo. (NOTA: un resistir, esquivar, parar, etc, NO cuenta como hechizo fallido y pasará al siguiente).
/castsequence Nova de Escarcha, Traslación
La primera vez que se pulsa el botón, se hará Nova, y la siguiente vez que se pulse hará Traslación para alejarse.
/castsequence [combat] Nova de Escarcha, Traslación
/castsequence reset=24 Nova de Escarcha, Traslación
La primera vez pulsada, hace Nova. Si se decide no hacer Traslación, después de 24 segundos, se reseteará a Nova. Dado que el cooldown de la Nova es de 24 segundos, estará listo para usarse de nuevo.
/castsequence Corrupción, Inmolar, Maldición de Agonía
Pulsa el botón 3 veces y lanzará los 3 DoT.
/castsequence reset=combat/target Corrupción, Inmolar, Maldición de Agonía
Cada vez que se cambie de objetivo (como, si por ejemplo el antiguo objetivo ya estuviera medio muerto y vas a por otro), o cada vez que sales de combate (porque la criatura muere antes de que lances todos los DoTs), resetea la secuencia para tí, dejándola lista para comenzar de nuevo.
Opciones
IMPORTANTE: Los nombres de las opciones condicionales deben ir en minúsculas
(Nota: el caracter barra vertical es para notar las diferentes posibilidades de un parámetro, pero no debe escribirse)
- actionbar:<número> – Evalúa ‘verdadero’ si la la barra de acción actual es la misma que el número indicado.
- button:<#> – Evalúa ‘verdadero’ si el botón fue usado para hacer ‘click’ en el hechizo, por defecto 1 (ver abajo).
- channeling:<hechizo> – Verdadero si estás canalizando el hechizo indicado. Si no se especifica hechizo, evalúa cualquier hechizo canalizándose.
- combat – Verdadero si estás en combate
- equipped:<ranuraItem>|<tipoItem>|<subtipoItem> – Verdadero si el objeto está equipado. El objeto puede ser cualquier ranura de inventario, clase de objeto subclase válido.
- exists y dead – Verdadero si tu ojetivo está muerto, o existe realmente.
- focus
- help – Verdadero si el objetivo es amigable.
- harm – Verdadero si el objetivo es hostil.
- indoors, outdoors – Verdadero si estás en interiores o exteriores respectvamente.
- modifier or modifier:shift|ctrl|alt – Verdadero si la tecla indicada se está pulsando cuando el comando se ejecuta.
- mounted, swimming, flying – Verdadero cuando vas montado, nadando o volando respectivamente.
- flyable – Verdadero si estás en un terreno apto para montura voladora
- pet:<tipo mascota O nombre mascota> – Verdadero si la mascota existe. Acepta tipo (Owl, Bear, Imp) o nombre (Fluffy, MrBigglesworth). Sin modificador (tan solo [pet]) es verdadero si existe cualquier mascota.
- stance or stance:# – Verdadero si estás en una postura (stance) o si estás en una en particular (ver abajo)
- stealth – Verdadero si estás camuflado.
- target=<unidad> – Opción especial. Cambia el objetivo del de por defecto de “target” a cualquier id de unidad válido.
La opción [equipped] funciona de la misma manera, aunque tiene algo de truco. El argumento puede ser una ranura de inventario, un tipo de objeto, o un subtipo.(Importante: los tipos dependen del idioma del juego; como norma general corresponderán con las categorías que aparecen en la casa de subastas).
Lista de ranuras de inventario:
- Two-Hand (2 manos)
- Bag (bolsa)
- Shirt (camisa)
- Chest (pechera)
- Back (espalda)
- Feet (pies)
- Finger (dedo)
- Hands (manos)
- Head (cabeza)
- Held In Off-hand (sotenido en la zurda)
- Legs (piernas)
- Neck (cuello)
- Ranged (a distancia)
- Off Hand (zurda)
- Shoulder (hombros)
- Tabard (Tabardo)
- Thrown (arrojadiza)
- Trinket (alhaja)
- Waist (cintura)
- One-Hand (una mano)
- Main Hand (mano diestra)
- Wrist (muñeca)
Algunos ejemplos:
/cast [equipped:Espadas dos manos] Golpe Mortal; Golpe Heroico
…usará Golpe Mortal si estás usando una espada a dos manos.
/cast [equipped:Espadas dos manos/Mazas dos manos/Hachas dos manos/Armas de Asta] Golpe Mortal
…usa el modificador ‘/’ que establece una condición ‘ó’. Ejecutará Golpe Mortal si CUALQUIERA de los tipos está equipado.
/cast [equipped:Escudos] Azote de escudo
…hará un Azote si tienes escudo equipado.
/cast [equipped:Escudos, equipped:Dagas] Embate con escudo
…hará Embate sólo si tienes una daga y un escudo equipados.
/cast [noequipped:Escudos, equipped:Mano Izquierda] Desenfreno
…activará Desenfreno si NO tienes escudo equipado, Y tienes algo equipado en la zurda. En teoría sólo se activaría con un arma en cada mano.
Los comandos /castsequence, /cast, /castrandom, /use, /userandom, /equip, /equipslot aceptan también el número de bolsa y ranura.
Opciones de Botón
La opción [button:<x>] funciona de manera similar al modificador de botón. Normalmente, si haces click izq. en un botón, ejecuta cualquier opción que haya en ese hechizo, o macro en nuestro caso. Sin embargo, si se establece la opción de botón, puedes cambiar el comportamiento para una macro particular.
El botón por defecto es 1, el Izquierdo. Nótese que cuando se activa un botón mediante una tecla asociada es igual que dar al botón Izquierdo. Los botones numerados son: 1 o LeftButton (izquierdo), 2 o RightButton (derecho), 3 o MiddleButton (central), 4 o Button4, 5 o Button5, … o cualquiera de los botones remapeados por el estado seguro de cabeceras (ni idea, pero es lo que pone).
/cast [button:2,target=player] Flash Heal; [help] Flash Heal
…lanza el Flash Heal (curación rápida) en un objetivo amigable, O si haces click con el botón derecho, lanzará Flash Heal sobre tí.
Foco (focus)
Video referente al Focus: [1]
Es una nueva característica que te permitirá guardar un objetivo. Ejemplo:
/focus target
…salvará tu objetivo actual como focus. Esto significa que en cualquier momento puedes usar /target focus para seleccionar la unidad designada con /focus target. Focus soporta las siguientes opciones. Ejemplo:
/cast [target=focus,exists] Polymorph
/castrandom [target=focus,exists] Polymorph, Polymorph: Pig, Polymorph: Turtle
…si quieres un polimorph aleatorio.
Se puede usar el comodín %f para referirse al foco (establecido con /focus) de la misma manera que %t o %n se refiere a tu objetivo. Por ejemplo: /decir Tengo el foco en %f Diría el nombre del personaje que tiene el foco.
Hover Targeting (selección “flotante”) El Hover Targeting, o la habilidad de lanzar hechizos en diferentes jugadores sin tener que seleccionarlos, tan solo pasando el cursor por encima de un marco de unidad protegido (en este caso party/raid/target/targettarget unitframe). Ejemplo:
/cast [target=mouseover,exist] Toque de sanación; Toque de sanación
…lanzará el Toque de Curación en la persona sobre la que esté el ratón al pulsar la macro sin tener que seleccionarlo. Un ejemplo más avanzado:
/cast [target=mouseover,exist,nomodifier:shift/ctrl/alt] Alivio presto;
[target=mouseover,exist,modifier:shift] Toque de sanación; [target=mouseover,exist,modifier:ctrl]
Rejuvenecimiento; [target=mouseover,exist,modifier:alt] Recrecimiento; [modifier:ctrl] Forma
felina; [modifier:shift] Forma de oso temible; [noswimming] Forma de viaje; [swimming] Forma
acuática
…lanzaría Alivio presto/Rejuvenecimiento/Recrecimiento/Toque de sanación si tu ratón está sobre una UnitFrame (el retrato de la party, por ejemplo) dependiendo de que modificador de tecla tengas pulsado (control, alt, …). Sin embargo, si no tienes el ratón sobre un UnitFrame (está en cualquier otro lugar de la pantalla) hará un cambio de forma según las opciones especificadas. En otras palabras, técnicamente es posible poner todas las curaciones estandar y cambios de forma en un solo botón que actúa dependiendo de si el ratón está sobre un UnitFrame y de los modificadores de tecla pulsados.
Opciones de Postura/Forma (Stance)
Funcionan de la misma manera. Si no se pone un número, es verdadero si el jugador está en una Postura cualquiera (los guerreros SIEMPRE están en una Postura). Si se indica un número será verdadero si la Postura está activa. Cada clase tiene unos valores:
-Guerrero: Stance:1 -Batalla, Stance:2 -Defensiva, Stance:3, Berseker
-Sacerdote: Stance:1 -Forma de Sombra (Shadowform)
-Druida: Stance:1 -Oso, Stance:2 -Acuática, Stance:3 -Gato, Stance:4 -Viaje, Stance:5 -Moonkin,Árbol
-Rogue: Stance:1 -Camuflado
/cast [stance:1] <Habilidad de postura batalla>; [stance:2] <Habilidad de postura defensiva>;
[stance:3] <Habilidad de postura berseker>
…reemplaza <Habilidad de postura *> por lo que quieras.
Las Auras de Paladin ya no son tratadas como Posturas en el sistema de opciones de Macros. Ten en cuenta que si mantienes una Postura (como un warrior que nunca hace el quest de la Postura Defensiva) tus números de Postura disminuyen, (ej. Postura Berserker sería el 2). Algunos ejemplos.
/cast [nostance] Bear Form
Si no estás en una forma, cambia a forma de oso.
/cast [stance:1] Overpower; [stance:2] Sunder Armor; [stance:3] Whirlwind
Si estás en Postura de Batalla usa Overpower, en Defensivo Sunder Armor, y Whirlwind en la Berseker.
/cast [stance:1] Growl; [stance:3] Claw
Usa Growl en forma de Oso o Claw en forma de Gato.
/cast [nostance:3] Cat Form
Te pone en forma de Gato si no lo estás. Si lo estás, esto NO te quitará la forma (puesto que no cumple la condición).
Opciones de Objetivo (Target Options)
La opción [target=unit] es una opción especial. En lugar de evaluar ‘verdadero’ o ‘falso’, cambia el objetivo del hechizo que venga a continuación y el objetivo de las otras opciones. “Unit” será un tipo de unidad válido, ej. “player”, “target”, “targettarget”, “party1″, “party1target”, etc etc.
Te en cuenta que cada hechizo tiene un objetivo de “objetivo” (target of target) por defecto. Por ejemplo:
/cast [help] Sanación superior
es lo mismo que:
/cast [target=target, help] Sanación superior
Hasta que no añadas una opción [target=unit], el objetivo por defecto será tu objetivo actual. Posibles ejemplos de [target=unit]:
/cast [target=player] Sanación relámpago
Este hechizo siempre hace Sanación relámpago sobre tí. Nótese que el objetivo actual NO cambia.
/cast [help] Sanación relámpago; [target=targettarget] Sanación relámpago
Este lanza Sanación relámpago en tu objetivo si es amigable, O lanzará el Sanación relámpago en el objetivo de tu objetivo.
/cast [help, combat] Sanación relámpago; [help, nocombat] Sanación superior; [target=targettarget, help, combat] Sanación relámpago; [target=player] Sanación superior
Esta hará una de 1) Lanzar Sanación relámpago si el objetivo es amigable y estás en combate, 2) lanza Sanación superior si el objetivo es amigo y no estás en combate, 3) lanza Sanación relámpago en el objetivo de tu objetivo si estás en combate y esa unidad es amistosa, o si ninguna de estas situaciones es cierta, lanza Sanación superior sobre tí mismo.
Si se usa el UnitId “none” actua como si NO tuvieras objetivo. Ejemplo:
/cast [target=none] Disipar Magia
Esto lanza Disipar y luego pregunta por un objetivo, independientemente de quién tengas seleccionado en ese momento.
Macros de Ejemplo
Macros Generales
Montura
/use [nomounted,outdoors] Brida de corcel de guerra negro
Esto intentará montar si estás en exteriores y no montado.
Usar venda
/use [target=player] Venda gruesa de paño
Esta macro intentará siempre ponerte una venda independientemente de tu objetivo seleccionado.
/use [modifier:alt,target=player] Venda gruesa de paño
/use [modifier:ctrl,target=pet] Venda gruesa de paño
/use [help] Venda gruesa de paño
1. Si pulsas la macro mientras aprietas la tecla ALT, te vendará a tí mismo.
2. Si pulsas la macro mientras aprietas la tecla CTRL, vendará a tu mascota.
3. Si pulsas la macro sin más, vendarás a un objetivo amigable.
/use [help,modifier:noalt] Venda gruesa de paño; [target=player] Venda gruesa de paño
Esta macro usará una venda en tu objetivo si es posible, o a tí mismo en caso contrario. Mientras no se pulse ALT, en cuyo caso siempre será sobre tí mismo.
Si añades /stopattack evitaras que se corte si estas atacando.
Macro de coordenadas
Con esta macro veras tu localización.
/script SetMapToCurrentZone() local x,y=GetPlayerMapPosition(“player”)DEFAULT_CHAT_FRAME:AddMessage(format(“%s, %s:
%.1f,%.1f”,GetZoneText(),GetSubZoneText(),x*100,y*100))
Emociones
Con esta macro ejecutaras una emoción
/besar
Equipar y usar
Con esta macro te pondrás un objeto que tiene uso y volverás a ponerte tu el actual en 2 clicks.
/equip Colgante del Guerrero de aguamarina
/use Colgante del Guerrero de aguamarina
/equip Colgante actual
Liberar espíritu
Bueno aunque esto parezca una tontería, es útil, ya que por ejemplo en bgs cuando caes al vació muchas veces no se puede liberar pulsando al botón, por tanto usáis la siguiente macro y os dejara en el ángel mas cercano.
/script RepopMe ()
¡¡Se acabo relogear en bgs para liberar!! XD
¡Adiós miles de barras de acción!
Como bien sabrás hay muchas veces que tienes que echar mano de las 4 barras de acción adicionales que el WoW te aporta pues bien aquí un par de macros sencillas para usar la mitad de espacio con las habilidades.
/use [button:1] Gran elekk verde
/use [button:2] Grifo dorado
Al hacer click izquierdo en la macro invocaras la montura de tierra, al hacer click derecho a la voladora.
/cast [modifier:alt] Patada; Golpe siniestro
Si haces click normal lanzaras golpe siniestro, si haces alt + click lanzaras una patada
/cast [button:2] Invocar diablillo; [modifier:alt]Invocar súcubo; Invocar a abisario
Esta última es una mezcla de las dos anteriores,al hacer click invocaras al abisario, al hacer click derecho invocaras al diablillo y al hacer alt + click invocaras a la súcubo. Personalmente no aconsejo esta última para hechizos normales ya que es mucho lió, pero si para cosas que se hacen cuando no estas en combate como puede ser invocar.
(En los tres tipos el comando puede ser cualquiera /cast, /castsequence, /use, etc…)
Macros de Clase
He de dar importancia a la opción de ahorro de espacio ya que es valido para cualquier clase
Guerrero
Habilidades especiales de cada actitud
/cast [stance:1] Represalias;[stance:2] Muro de escudo; [stance:3] Letalidad
Cargar-seccionar
/cast [nocombat] Cargar; Seccionar
Si no estas en combate usaras cargar y si si lo estas usaras seccionar. Esto es bueno para lanzarte contra tu enemigo y que no pueda salir corriendo muy rápido.
Reflejo de hechizos
/equip <Nombre de escudo>
/cast Reflejo de hechizos
/equip <Nombre de arma 2M o arma izquierda>
Cuando pulses en la macro te pondrá el escudo y si vuelves a pulsar te lanzara reflejo con hechizos y volveras a tu arma o armas principales. Esto es bueno tanto en PVP como en PVE.
SI estas en actitud de batalla hace represalias, si estas en defensiva Muro de escudo y si estas en rabiosa Letalidad
Paladín
Pícaro
Porrazo instantáneo
/targetenemy
/cast porrazo
Esta macro hace que en un PVP contra otro pícaro, solo tienes que ir clicando continuamente la macro, en cuanto el otro pícaro vaya a ser visto por tu personaje ya lo stunea, mucho más rápido de lo que podrías hacerlo coordinando vista y el movimiento de la mano.
Poner venenos con 1 clic
/use <nombre del veneno>
/use [button:1] 16; [button:2] 17
Al clicar con el botón izquierdo pondrá el veneno en el arma principal, al clicar con el botón derecho en la otra.
Esfumarse sin peligro
/cast Paso de las sombras
/stopcasting
/cast Esfumarse (Rango X)
Con esta macro te podrás esfumar sin peligro a que te estén tirandoun hechizo o por si tienes DoTs para quitartelos y esfumarte sin problemas.
Druida
Mago
Piro-Bola de Fuego
Lanza Piroexplosión como apertura si no estás en combate, bola de fuego si estás en combate
/cast [nocombat] Piroexplosión; Bola de Fuego
Explosión Arcana Definitiva
Lanza Deflagración Arcana rango 1 cuando no estás en combate, o tu rango máximo cuando estás en combate. Muy útil para descubrir pícaros/druidas en sigilo. Por ejemplo, protegiendo la bandera de tu facción en la Garganta Grito de Guerra.
#Showtooltip Deflagración Arcana
/cast [nocombat] Deflagración Arcana(Rango 1); Deflagración Arcana
Rompe con el Cono de Frío
Lanza Nova de Escarcha en tu primera pulsación, luego Cono de Frío. Este macro resetea después de 24 segundos.
/castsequence reset=24 Nova de Escarcha, Cono de Frío
Zambombazo de Fuego Mayor
#showtooltip Piroexplosión
/cast Presencia de la Mente
/stopcasting
/cast Poder Arcano
/stopcasting
/cast Piroexplosión
Brujo
Chamán
Unas muy sencillas pero útiles xD:
-Elemental
Cadena de relámpagos crítica (Para PvP)
/cast Maestría elemental
/stopcast
/cast Cadena de relámpagos (Rango X)
-Resto
Curación instantanea a ti mismo (Útil también para PvP)
/Target (nombre de uno mismo) ej: /Target Poker
/Cast Presteza de la naturaleza
/Cast Ola de Sanación (Rango X)
Elemental – Resto
Heal critica instant a ti mismo)
/Target (nombre de uno mismo) ej: /Target Dispersador
/cast Maestría elemental
/stopcast
/Cast Presteza de la naturaleza
/Cast Ola de Sanación (Rango X)
Si se quiere añadir un abalorio para aumentar la sanación con un simple use 13 o use 14 bastaria.
Cazador
Sacerdote
Macros Avanzadas
Dado que en gplp no se permiten addons, aquí iremos incluyendo algunas macros que pueden ser de utilidad.
/script local a,b,c=SendChatMessage,PickupInventoryItem,PickupContainerItem;CloseMerchant();for i = 1,18 do if (i~=4) then
b(i);c(4,i); end end if UnitManaMax(“player”)>8000 then a(“¡Ahora soy DPS!”); else a(“¡Ahora soy healer!”); end
La clásica macro de cambio de equipo. Necesaria una bolsa de 18 casillas, si queréis cambiar todo el equipo útil (es decir, todo menos el tabardo, camisa). Para utilizar la macro tal cual necesitareis una bolsa así, si no no tengo ni idea de que pasara (podría ser peligroso para vuestros items, aunque no es probable)
Tenéis que tener los items en la bolsa 4 (creo que es la última, la que esta más a la izquierda) y en este orden:
1 = cabeza
2 = cuello
3 = hombros
4 = camisa (pero este no lo cambio, es un hueco libre)
5 = pecho
6 = cintura
7 = piernas
8 = pies
9 = muñeca
10 = guantes
11 = dedo 1
12 = dedo 2
13 = abalorio 1
14 = abalorio 2
15 = espalda
16 = mano derecha
17 = mano izquierda
18 = A distancia (varita, totem, trabuco, etc)
Si no ponéis ningún objeto en el hueco, pues simplemente os quitara el objeto y lo pondrá ahí cuando uséis la macro, y luego os equipara. Podéis cambiar la vida (8000) y los mensajes a vuestra conveniencia.
/script for i=1,GetNumRaidMembers()-1 do local s=”raid”..i c=UnitName(s)
if((UnitHealth(s)<2500)and(UnitHealth(s)>1)) then DEFAULT_CHAT_FRAME:AddMessage(“CUIDADO “..c..” se esta MURIENDO!”) end end
Esta macro, que podéis incorporar después de un /cast (vuestra habilidad más popular o cura) os puede avisar de los miembros de la raid con menos de X de vida (2500 en el ejemplo). Quizá sea mejor simplemente sacar el grupo, pero puede servir para despistados.
/run for i=1,GetNumRaidMembers() do s=”raid”..i c=UnitName(s) local h=0 for j=1,40 do A=UnitBuff(s,j)
if(A==”Nombre EXACTO del bufo”) then h=1 end end if h==0 then DEFAULT_CHAT_FRAME:AddMessage(c..” no tiene”) end end
Esta os servirá para saber que personajes de una raid no tienen un determinado bufo, muy útil a la hora de bufear. Podéis hacer un /cast bufo antes y luego añadir eso, y podéis saber a quien bufear. Obviamente, debéis cambiar “Nombre exacto del bufo” por el nombre del bufo (importan las mayúsculas).
/run for i=1,GetNumRaidMembers() do s=”raid”..i c=UnitName(s) local h=0 for j=1,40 do A=UnitBuff(s,j)
if (A==”Nombre 1º BUFO”)or(A==”Nombre 2º bufo”) then h=1 end end if h==0 then DEFAULT_CHAT_FRAME:AddMessage(c) end end
Lo mismo que antes solo que ahora mirará si tiene un bufo u otro distinto, y si tiene cualquiera de los dos no os avisa. Util por si hay bufos grupales que sustituyen a los normales como “Luminosidad Arcana” de mago, “Don de lo salvaje” o simplemente para no distinguir entre “Bendición de reyes” y “Bendición de reyes superior”.
Enlaces externos
- Equivalencia de comandos
- Guía detallada de las Opciones
- Macros en 2.0 (WoWWiki)
- Tipos y subtipos de equipo (WoWWiki)
- Tipos de unidades (WoWWiki)
- Usuario de GPLP Death (Deathnoseque)
- Traducido de foros y páginas inglesas (Cogwheel, Iridel, Neuro, los colaboradores de Wowwiki y Slouken, padre de la API y el motor de macros).
- WowEurope
Fantástico
ResponderEliminar